直角三角形 計算機 0゚<θ<90゚
はじめに
日常の角度曲げ作業で、図面を見ながら、関数電卓で、直角三角形の角度や各辺の長さを求める場合が多くあります。 このため、曲げ作業では、
関数電卓は必需品になっています。
しかし、関数電卓では図面が複雑な場合、解析に時間を要し、労働生産性の低下を招くことになります。
とくに曲げ作業に必要なCADデータが転嫁されていない場合に、顕著にあらわれます。
関数電卓で計算する場合とパソコンによる計算との比較は、積算時間、使い勝手や入力の煩雑さ、入力間違いの点を捕らえても、歴然としています。
直角三角形計算機のイメージ
入力は、2箇所のみにしてください。
セル位置 |
B |
C |
D |
E |
14 |
入 力 欄 |
15 |
底 辺 |
高 さ |
斜 辺 |
角 度 |
16 |
100 |
100 |
|
|
セル位置 |
B |
C |
D |
E |
20 |
出 力 欄 |
21 |
底 辺 |
高 さ |
斜 辺 |
角 度 |
22 |
100.00 |
100.00 |
141.42 |
45.00 |
|
|
直角三角形計算機で使用する関数は下記のとおりです。
I F |
指定された条件が TRUE (真) のとき真の場合を返し、FALSE (偽) のとき偽の場合を返します。 |
AND |
すべての引数が TRUE のとき、TRUE を返します。引数が 1 つでも FALSE である場合、戻り値は FALSE になります。
角度の入力規則などに使用します。
|
COUNT |
引数リストに含まれる数値の個数をかえします。
引数リストの各項目には、数値、名前、配列、またはセル参照を指定できます。
|
CHOOSE |
インデックスを使用して、引数リストから特定の数値、セル参照、名前、数式、関数、または文字列を一つ選択します。 |
SIN θ/180*PI() |
θ 度のサインをかえします |
正 接 (TAN ) |
正接……TANθ=C/B 角度のタンジェントを返します C寸法=TANθ*B |
正 弦 (SIN ) |
正弦……SINθ=C/A 角度のサインを返します C寸法=SINθ*A |
余 弦 (COS) |
余弦……COSθ=B/A 角度のコサインを返します B寸法=COSθ*A |
DEGREES |
ラジアンを度に変換します。 |
アークサイン(ASIN) |
数値のアークサインをかえします。 |
アークコサイン(ACOS) |
数値のアークコサインをかえします。 |
アークタンジェント(ATAN) |
数値のアークタンジェントをかえします。 |
SQRT |
正の平方根を返します。 |
( ^ ) キャレット |
べき乗の演算子です。 |
参考 計算の基礎 三角関数の計算 ピタゴラスの計算 演算子 関数
その他---エクセルの関数ヘルプに各関数の詳細が記載されています。
使用関数は、拘りません。他によい関数があれば使用してください。
なお、出力欄の数式の中で、入力欄の空白セルを参照しているダイアログが出ますが、該当しないので無視してください。
|
組み合わせとCHOOSE関数インデックスの計算結果による値の位置の対比
組み数 |
入力組合わせの
(セル位置) |
左の組合わせの
(値の位置) |
1 |
B16 C16 |
3 |
2 |
B D |
4 |
3 |
B E |
6 |
4 |
C D |
5 |
5 |
C E |
7 |
6 |
D E |
8 |
|
|
B |
C |
D |
E |
入 力 欄 |
底 辺 |
高 さ |
斜 辺 |
角 度 |
100 |
100 |
|
|
組み数 |
入力組合わせの
(セル位置) |
左の組合わせの
(値の位置) |
. |
1 |
B16 C16 |
3 |
|
|
|
|
数値の3(値の位置)は、B16とC16に入力されている場合の数式の答えで、B22:E22の数式に入力する値の位置です。
B16とD16に入力されたBとDの組み合わせの場合は、値の位置が 4 ということになります。
したがって、3〜8が入力が必要となる値の位置になり、1と2は空番となります。 |
入力組み合わせが6通りになります
インデックスは、=COUNT(B16)+COUNT(C16)*2+COUNT(D16)*3+COUNT(E16)*5で構成されています。
この式の答えが値の位置になります。
各組み合わせの値の位置が、同じ数値が重ならないように係数を設定してください。
係数を設定とは、例えば、COUNT(D16)*3の3を他の数値(4や6など)に置き換えるということです。 |
対比表の見方の説明
☆以下底辺と高さ:B16:C16セルが入力された場合で説明
組み合わせ(セル位置)について(重複説明になりますが!)
底辺、高さ、斜辺、角度の入力組み合わせで6通りになります。
CHOOSE関数のインデックスの数式による計算結果が同じ数値にならないように係数を設定します
ここでは、COUNT(B16)+COUNT(C16)*2+COUNT(D16)*3+COUNT(E16)*5を使用してます。
値が同じにならないよう任意に設定することができます<29個まで。
大きい数値を設定すると値の位置が大きくなります。
CHOOSE関数のインデックスの計算結果による入力すべき関数の値の位置について
B16:E16の組み合わせとインデックスの計算結果による値の位置対比表はB22:E22に入力すべき値の位置をあらわします。
B16、 C16に入力があった場合、B22:E22の関数式の値が引数リスト3の位置に当該計算式やセルの位置を入力することになります。
当該計算式とは前もって作っておく関数式やB16:E16の入力セルの位置になります。
下部の参考を参照してください。
☆以下底辺:B22セルで説明
数式の作成
IF(COUNT(B16:E16)=2,CHOOSE(COUNT(B16)+COUNT(C16)*2+COUNT(D16)*3+COUNT(E16)*5,
1,2,B16,B16,SQRT(D16^2-C16^2),B16,C16*TAN((90-E16)/180*PI()),D16*COS(E16/180*PI()),),"")になります。
なお、8番目の位置のD16*COS(E16/180*PI()),),"") は D16*COS(E16/180*PI()),))で支障ありません。
以下、B22セルに入力するこの式を解析します。
数式のIF関数の説明
IF関数の倫理式について
倫理式はCOUNT(B16:E16)=2になります。
B16:E16に入力されているセル数が2の場合、TRUE (真) をかえします。
B16:E16に入力されているセル数が2以外の場合、FALSE(偽) をかえします。
真の場合の式について
CHOOSE(COUNT(B16)+COUNT(C16)*2+COUNT(D16)*3+COUNT(E16)*5,
1,2,B16,B16,SQRT(D16^2-C16^2),B16,C16*TAN((90-E16)/180*PI()),D16*COS(E16/180*PI()),),になります。
実務的には、B16:E16の入力条件の組み合わせにより、各値の位置に前もって作った関数式を値の位置にコピー、入力します。
事例
D16とE16に入力された場合
斜辺と角度が分かっているのでB22(底辺)に入力すべき計算式[ D16*COS(E16/180*PI()) ]を真の場合の数式の8番目の値の
位置に入力することになります。
偽の場合の式について
" "になります.
" "は未入力の状態をあらわします。
CHOOSE関数の説明
CHOOSE関数のインデックスについ
インデックスはCOUNT(B16)+COUNT(C16)*2+COUNT(D16)*3+COUNT(E16)*5にしています。
*2、*3、*5 は拘りません。
CHOOSE関数の値について
1,2,B16,B16,SQRT(D16^2-C16^2),B16,C16*TAN((90-E16)/180*PI()),D16*COS(E16/180*PI())になります。
最初の1,2,−,−,−,は、値の位置になります。(蛇足、最大29まで入力できます。)
実務的には、1〜8まで連番を付しておき、上記の組み合わせ係数とインデックスの位置対比表にもとずき、組み合わせ係数と
インデックスの値の位置対比表から該当する、値の位置に、必要な数式を入力します。
ここでは、B22(底辺)を求めていますので、値3の位置に入力済みのB16を入力すれば100がかえります。。
従って、入力条件に基ずき、求める辺や角度を計算する数式を前もって作っておけば、楽に作業ができます。。
前もって作っておく関数式(青字は前もって作っておく関数式)
B16 、 C16が入力されている場合
SQRT(B16^2+C16^2) はD22のCHOOSE関数の値3の位置に入力します。(底辺と高さが入力されている斜辺を求める式)
ATAN(C16/B16)*180/PI( ) は、E22のCHOOSE関数の値3の位置に入力します。(底辺と高さが入力されている角度を求める式)
ATAN(C16/B16)*180/PI( ) は、DEGREES(ATAN(C16/B16)でも支障ありません。
その他
…*SIN(…/180*PI())
SQRT(…^2ー…^2)
…/SIN(…/180*PI())
…はセル位置になります。
など、必要な関数式を作っておきます。
数式は拘りません。
角度入力セルの入力規則の作成
条件が2つ以上ある場合(入力角度が0度以上でかつ、90度未満)他の関数とともに使用します
ここでは、AND関数を使用します。
=IF(AND(入力セル>0,入力セル<90),入力セル,"")の入力式になります。。
参考 数式の組み方の順序
セル位置 |
B |
C |
D |
E |
14 |
入 力 欄 |
15 |
底 辺 |
高 さ |
斜 辺 |
角 度 |
16 |
100 |
100 |
|
|
セル位置 |
B |
C |
D |
E |
20 |
出 力 欄 |
21 |
底 辺 |
高 さ |
斜 辺 |
角 度 |
22 |
100.00 |
100.00 |
141.42 |
45.00 |
組み合わせとCHOOSE関数インデックスの計算結果による値の位置の対比
組み数 |
入力組合わせの(セル位置) |
左の組合わせの値の位置) |
組み数 |
入力組合わせの(セル位置)
|
左の組合わせの(値の位置) |
1 |
B16 C16 |
3 |
4 |
C D |
5 |
2 |
B D |
4 |
5 |
C E |
7 |
3 |
B E |
6 |
6 |
D E |
8 |
値の位置に貼り付ける計算式一覧
値の位置 |
底 辺(B) |
高 さ(C) |
斜 辺(D) |
角 度(E) |
1 |
1 |
1 |
1 |
1 |
2 |
2 |
2 |
2 |
2 |
3 |
B16 |
C16 |
SQRT(B16^2+C16^2) |
DEGREES(ATAN(C16/B16)) |
4 |
B16 |
SQRT(D16^2-B16^2) |
D16 |
DEGREES(ACOS(B16/D16)) |
5 |
SQRT(D16^2-C16^2) |
C16 |
D16 |
DEGREES(ASIN(C16/D16)) |
6 |
B16 |
B16*TAN(E16/180*PI()) |
B16/COS(E16/180*PI()) |
E16 |
7 |
C16*TAN((90-E16)/180*PI()) |
C16 |
C16/SIN(E16/180*PI()) |
E16 |
8 |
D16*COS(E16/180*PI()) |
D16*SIN(E16/180*PI()) |
D16 |
E16 |
出力欄の数式
底 辺 |
1,2,B16,B16,SQRT(D16^2-C16^2),B16,C16*TAN((90-E16)/180*PI()),D16*COS(E16/180*PI()),)) |
高 さ |
1,2,C16,SQRT(D16^2-B16^2),C16,B16*TAN(E16/180*PI()),C16,D16*SIN(E16/180*PI()),)) |
斜 辺 |
1,2,SQRT(B16^2+C16^2),D16,D16,B16/COS(E16/180*PI()),C16/SIN(E16/180*PI()),D16,)) |
角 度 |
1,2,DEGREES(ATAN(C16/B16)),DEGREES(ACOS(B16/D16)),DEGREES(ASIN(C16/D16)),E16,E16,E16,)) |
各数式の前には、IF(COUNT(B16:E16)=2,CHOOSE(COUNT(B16)+COUNT(C16)*2+COUNT(D16)*3+COUNT(E16)*5,が
つきます。
曲げ作業に関わる直角三角形の三角関数を取り上げました。
使用関数は、使い易い慣れた関数を使用しましょう。
ピタゴラスの定理、三角関数、相似形、直線と角度などは図面の展開や曲げ作業によく使用しますので慣れておきましょう。
エクセルシートから[ 挿入 ] 、[ 関数F ] 、[ 数学/三角 ] をクリックして求める関数を[OK]で入力画面、や、「数式」、
「数学・三角」から入力画面になりますので試してみましょう。(バージョンにより、ツールの説明が異なります。)
直角三角形計算機のダウンロードについて
名 前 |
直角三角形計算機 ( 0゚<θ<90゚ ) |
動 作 O S |
WindowsXP 以降のバージョン |
動 作 環 境 |
Microsoft Excel 2000以上 |
ファイルの種類 |
zip形式 右クリックで、[名前を付けてリンク先を保存(K)] を選択してください。
アンインストールは、ファイルごと削除してください。 |
ファイルのサイズ |
35.000bites |
制 作 者 |
Office T&S |
著 作 権 |
著作権はすべて制作者である Office T&S が所有します。 |
利用について |
営利目的は禁止します。 |
免 責 事 項 |
このプログラムの使用によって、いかなる問題が生じても制作者は一切の責任を負いません。
プログラムの内容などは、予告なしに変更することがあります。 |
説 明 |
計算機のみで、内容の修正は行いません。
使用方法、内容は、このページの説明と同じです。
誤操作を防ぐため、保護をかけています。
保護の解除はパスワードが必要になりますので、さわらないでください。 |
ダウンロード |
ダウンロードはここからです |
TOPページにリンク
要約版にリンク
|
|